stock sendmail 8.10.0 with $Id -> $Sendmail

19 files changed, 596 insertions, 0 deletions

diff --git a/gnu/usr.sbin/sendmail/devtools/M4/UNIX/all.m4 b/gnu/usr.sbin/sendmail/devtools/M4/UNIX/all.m4
new file mode 100644
index 00000000000..828950ea68d
--- /dev/null
+++ b/gnu/usr.sbin/sendmail/devtools/M4/UNIX/all.m4
@@ -0,0 +1,38 @@
+divert(-1)
+#
+# Copyright (c) 1999 Sendmail, Inc. and its suppliers.
+#	All rights reserved.
+#
+# By using this file, you agree to the terms and conditions set
+# forth in the LICENSE file which can be found at the top level of
+# the sendmail distribution.
+#
+#
+#  Definitions for Makefile construction for sendmail
+#
+#	$Sendmail: all.m4,v 8.7 1999/10/13 07:08:36 gshapiro Exp $
+#
+divert(0)dnl
+ALL=${BEFORE} ${LINKS} bldTARGETS
+
+all: ${ALL}
+
+clean: bldCLEAN_TARGETS
+
+define(`bldADD_SRC', ${$1SRCS} )dnl
+SRCS=bldFOREACH(`bldADD_SRC(', bldC_PRODUCTS)
+define(`bldADD_OBJS', ${$1OBJS} )dnl
+OBJS=bldFOREACH(`bldADD_OBJS(', bldC_PRODUCTS)
+
+ifdef(`bldNO_INSTALL', `divert(-1)')
+install: bldINSTALL_TARGETS
+
+install-strip: bldINSTALL_TARGETS ifdef(`bldSTRIP_TARGETS', `bldSTRIP_TARGETS')
+ifdef(`bldNO_INSTALL', `divert(0)')
+
+divert(bldDEPENDENCY_SECTION)
+################  Dependency scripts
+include(confBUILDTOOLSDIR/M4/depend/ifdef(`confDEPEND_TYPE', `confDEPEND_TYPE',
+`generic').m4)dnl
+################  End of dependency scripts
+divert(0)
diff --git a/gnu/usr.sbin/sendmail/devtools/M4/UNIX/defines.m4 b/gnu/usr.sbin/sendmail/devtools/M4/UNIX/defines.m4
new file mode 100644
index 00000000000..df2adbe846a
--- /dev/null
+++ b/gnu/usr.sbin/sendmail/devtools/M4/UNIX/defines.m4
@@ -0,0 +1,121 @@
+divert(-1)
+#
+# Copyright (c) 1999-2000 Sendmail, Inc. and its suppliers.
+#	All rights reserved.
+#
+# By using this file, you agree to the terms and conditions set
+# forth in the LICENSE file which can be found at the top level of
+# the sendmail distribution.
+#
+#
+#  Definitions for Makefile construction for sendmail
+#
+#	$Sendmail: defines.m4,v 8.27 2000/02/26 01:32:06 gshapiro Exp $
+#
+divert(0)dnl
+
+# C compiler
+CC=	confCC
+CCOPTS= ifdef(`confCCOPTS', `confCCOPTS', ` ') ifdef(`confMT', ifdef(`confMTCCOPTS', `confMTCCOPTS', `'), `')
+
+# C Linker
+LD=	ifdef(`confLD', `confLD', `confCC')
+LDOPTS=	ifdef(`confLDOPTS', `confLDOPTS') ifdef(`confMT', ifdef(`confMTLDOPTS', `confMTLDOPTS', `'), `')
+LDOPTS_SO= ${LDOPTS} ifdef(`confLDOPTS_SO', `confLDOPTS_SO', `-shared')
+
+# Shell
+SHELL=	confSHELL
+
+# use O=-O (usual) or O=-g (debugging)
+O=	ifdef(`confOPTIMIZE', `confOPTIMIZE', `-O')
+
+# Object archiver
+AR=     ifdef(`confAR', `confAR', `ar')
+AROPTS=	ifdef(`confAROPTS', `confAROPTS', `crv')
+
+# Ranlib (or echo)
+RANLIB= ifdef(`confRANLIB', `confRANLIB', `ranlib')
+RANLIBOPTS=	ifdef(`confRANLIBOPTS', `confRANLIBOPTS', `')
+
+# Object stripper
+STRIP=	ifdef(`confSTRIP', `confSTRIP', `strip')
+STRIPOPTS=	ifdef(`confSTRIPOPTS', `confSTRIPOPTS', `')
+
+# environment definitions (e.g., -D_AIX3)
+ENVDEF= ifdef(`confENVDEF', `confENVDEF') ifdef(`conf_'bldCURRENT_PRD`_ENVDEF', `conf_'bldCURRENT_PRD`_ENVDEF')
+
+# location of the source directory
+SRCDIR=	ifdef(`confSRCDIR', `confSRCDIR', `_SRC_PATH_')
+
+# include directories
+INCDIRS= confINCDIRS
+
+# library directories
+LIBDIRS=confLIBDIRS
+
+# Additional libs needed
+LIBADD= ifdef(`conf_'bldCURRENT_PRD`_LIBS', `conf_'bldCURRENT_PRD`_LIBS') 
+
+# libraries required on your system
+#  delete -l44bsd if you are not running BIND 4.9.x
+LIBS= ${LIBADD} ifdef(`confLIBS', `confLIBS')
+
+# location of sendmail binary (usually /usr/sbin or /usr/lib)
+BINDIR=	ifdef(`confMBINDIR', `confMBINDIR', `/usr/sbin')
+
+# location of "user" binaries (usually /usr/bin or /usr/ucb)
+UBINDIR=ifdef(`confUBINDIR', `confUBINDIR', `/usr/bin')
+
+# location of "root" binaries (usually /usr/sbin or /usr/etc)
+SBINDIR=ifdef(`confSBINDIR', `confSBINDIR', `/usr/sbin')
+
+# location of "libexec" binaries (usually /usr/libexec or /usr/etc)
+EBINDIR=ifdef(`confEBINDIR', `confEBINDIR', `/usr/libexec')
+
+# additional .c files needed
+SRCADD= ifdef(`confSRCADD', `confSRCADD')
+
+ifdef(`conf_'bldCURRENT_PRD`_SRCADD', `bldLIST_PUSH_ITEM(`bldSOURCES', `conf_'bldCURRENT_PRD`_SRCADD')')
+
+# additional .o files needed
+OBJADD=	ifdef(`confOBJADD', `confOBJADD')
+bldCURRENT_PRODUCT`OBJADD'= ifdef(`conf_'bldCURRENT_PRD`_OBJADD', `conf_'bldCURRENT_PRD`_OBJADD') ifdef(`confLIBADD', `bldADD_EXTENSIONS(`a', confLIBADD)', `') 
+
+# copy files
+CP= ifdef(`confCOPY', `confCOPY', `cp')
+
+###################  end of user configuration flags  ######################
+
+BUILDBIN=confBUILDBIN
+COPTS=	-I. ${INCDIRS} ${ENVDEF} ${CCOPTS}
+CFLAGS=	$O ${COPTS} ifdef(`confMT', ifdef(`confMTCFLAGS', `confMTCFLAGS -DXP_MT', `-DXP_MT'), `')
+
+BEFORE=	confBEFORE
+
+LINKS=ifdef(`bldLINK_SOURCES', `bldLINK_SOURCES', `')
+
+bldCURRENT_PRODUCT`SRCS'= bldSOURCES ${SRCADD}
+bldCURRENT_PRODUCT`OBJS'= bldSUBST_EXTENSIONS(`o', bldSOURCES) ifdef(`bldLINK_SOURCES', `bldSUBST_EXTENSIONS(`o', bldLINK_SOURCES)') ${OBJADD} ${bldCURRENT_PRODUCT`OBJADD'}
+bldCURRENT_PRODUCT`SMDEPLIBS'= ifdef(`bldSMDEPLIBS', `bldSMDEPLIBS', `')
+bldCURRENT_PRODUCT`TARGET_LINKS'= ifdef(`bldTARGET_LINKS', `bldTARGET_LINKS', `')
+
+bldPUSH_ALL_SRCS(bldCURRENT_PRODUCT`SRCS')dnl
+
+ifdef(`bldBIN_TYPE', , `define(`bldBIN_TYPE', `U')')dnl
+ifdef(`bldINSTALL_DIR', , `define(`bldINSTALL_DIR', `U')')dnl
+
+NROFF=	ifdef(`confNROFF', `confNROFF', `groff -Tascii')
+MANDOC=	ifdef(`confMANDOC', `confMANDOC', `-man')
+
+INSTALL=ifdef(`confINSTALL', `confINSTALL', `install')
+
+# User binary ownership/permissions
+UBINOWN=ifdef(`confUBINOWN', `confUBINOWN', `bin')
+UBINGRP=ifdef(`confUBINGRP', `confUBINGRP', `bin')
+UBINMODE=ifdef(`confSBINMODE', `confSBINMODE', `555')
+
+# Setuid binary ownership/permissions
+SBINOWN=ifdef(`confSBINOWN', `confSBINOWN', `root')
+SBINGRP=ifdef(`confSBINGRP', `confSBINGRP', `bin')
+SBINMODE=ifdef(`confSBINMODE', `confSBINMODE', `4555')
+
diff --git a/gnu/usr.sbin/sendmail/devtools/M4/UNIX/executable.m4 b/gnu/usr.sbin/sendmail/devtools/M4/UNIX/executable.m4
new file mode 100644
index 00000000000..0e7d5b82805
--- /dev/null
+++ b/gnu/usr.sbin/sendmail/devtools/M4/UNIX/executable.m4
@@ -0,0 +1,41 @@
+divert(-1)
+#
+# Copyright (c) 1999 Sendmail, Inc. and its suppliers.
+#	All rights reserved.
+#
+# By using this file, you agree to the terms and conditions set
+# forth in the LICENSE file which can be found at the top level of
+# the sendmail distribution.
+#
+#
+#  Definitions for Makefile construction for sendmail
+#
+#	$Sendmail: executable.m4,v 8.18 1999/10/13 07:08:36 gshapiro Exp $
+#
+divert(0)dnl
+include(confBUILDTOOLSDIR`/M4/'bldM4_TYPE_DIR`/links.m4')dnl
+bldLIST_PUSH_ITEM(`bldC_PRODUCTS', bldCURRENT_PRODUCT)dnl
+bldPUSH_TARGET(bldCURRENT_PRODUCT)dnl
+bldPUSH_INSTALL_TARGET(`install-'bldCURRENT_PRODUCT)dnl
+bldPUSH_CLEAN_TARGET(bldCURRENT_PRODUCT`-clean')dnl
+bldPUSH_ALL_SRCS(bldCURRENT_PRODUCT`SRCS')dnl
+bldPUSH_STRIP_TARGET(`strip-'bldCURRENT_PRODUCT)dnl
+
+include(confBUILDTOOLSDIR`/M4/'bldM4_TYPE_DIR`/defines.m4')
+divert(bldTARGETS_SECTION)
+bldCURRENT_PRODUCT: ${bldCURRENT_PRODUCT`OBJS'} ${bldCURRENT_PRODUCT`SMDEPLIBS'}
+	${CC} -o bldCURRENT_PRODUCT ${LDOPTS} ${LIBDIRS} ${bldCURRENT_PRODUCT`OBJS'} ${LIBS}
+
+ifdef(`bldLINK_SOURCES', `bldMAKE_SOURCE_LINKS(bldLINK_SOURCES)')
+
+ifdef(`bldNO_INSTALL', ,
+`install-`'bldCURRENT_PRODUCT: bldCURRENT_PRODUCT
+	${INSTALL} -c -o ${bldBIN_TYPE`'BINOWN} -g ${bldBIN_TYPE`'BINGRP} -m ${bldBIN_TYPE`'BINMODE} bldCURRENT_PRODUCT ${DESTDIR}${bldINSTALL_DIR`'BINDIR}
+ifdef(`bldTARGET_LINKS', `bldMAKE_TARGET_LINKS(${bldINSTALL_DIR`'BINDIR}/bldCURRENT_PRODUCT, ${bldCURRENT_PRODUCT`'TARGET_LINKS})')')
+
+strip-`'bldCURRENT_PRODUCT: bldCURRENT_PRODUCT
+	${STRIP} ${STRIPOPTS} ${DESTDIR}${bldINSTALL_DIR`'BINDIR}`'/bldCURRENT_PRODUCT
+
+bldCURRENT_PRODUCT-clean:
+	rm -f ${OBJS} bldCURRENT_PRODUCT ${MANPAGES}
+divert(0)
diff --git a/gnu/usr.sbin/sendmail/devtools/M4/UNIX/footer.m4 b/gnu/usr.sbin/sendmail/devtools/M4/UNIX/footer.m4
new file mode 100644
index 00000000000..664a0baac09
--- /dev/null
+++ b/gnu/usr.sbin/sendmail/devtools/M4/UNIX/footer.m4
@@ -0,0 +1,19 @@
+divert(-1)
+#
+# Copyright (c) 1999 Sendmail, Inc. and its suppliers.
+#	All rights reserved.
+#
+# By using this file, you agree to the terms and conditions set
+# forth in the LICENSE file which can be found at the top level of
+# the sendmail distribution.
+#
+#
+#  Definitions for Makefile construction for sendmail
+#
+#	$Sendmail: footer.m4,v 8.2 1999/05/13 16:16:35 gshapiro Exp $
+#
+divert(0)dnl
+################  Dependency scripts
+include(confBUILDTOOLSDIR/M4/depend/ifdef(`confDEPEND_TYPE', `confDEPEND_TYPE',
+`generic').m4)dnl
+################  End of dependency scripts
diff --git a/gnu/usr.sbin/sendmail/devtools/M4/UNIX/library.m4 b/gnu/usr.sbin/sendmail/devtools/M4/UNIX/library.m4
new file mode 100644
index 00000000000..3e2833cb251
--- /dev/null
+++ b/gnu/usr.sbin/sendmail/devtools/M4/UNIX/library.m4
@@ -0,0 +1,34 @@
+divert(-1)
+#
+# Copyright (c) 1999 Sendmail, Inc. and its suppliers.
+#	All rights reserved.
+#
+# By using this file, you agree to the terms and conditions set
+# forth in the LICENSE file which can be found at the top level of
+# the sendmail distribution.
+#
+#
+#  Definitions for Makefile construction for sendmail
+#
+#	$Sendmail: library.m4,v 8.6 1999/08/13 21:31:08 gshapiro Exp $
+#
+divert(0)dnl
+include(confBUILDTOOLSDIR`/M4/'bldM4_TYPE_DIR`/links.m4')dnl
+bldLIST_PUSH_ITEM(`bldC_PRODUCTS', bldCURRENT_PRODUCT)dnl
+bldPUSH_TARGET(bldCURRENT_PRODUCT`.a')dnl
+bldPUSH_INSTALL_TARGET(`install-'bldCURRENT_PRODUCT)dnl
+bldPUSH_CLEAN_TARGET(bldCURRENT_PRODUCT`-clean')dnl
+
+include(confBUILDTOOLSDIR`/M4/'bldM4_TYPE_DIR`/defines.m4')
+divert(bldTARGETS_SECTION)
+bldCURRENT_PRODUCT.a: ${BEFORE} ${bldCURRENT_PRODUCT`OBJS'}
+	${AR} ${AROPTS} bldCURRENT_PRODUCT.a ${bldCURRENT_PRODUCT`OBJS'}
+	${RANLIB} ${RANLIBOPTS} bldCURRENT_PRODUCT.a
+ifdef(`bldLINK_SOURCES', `bldMAKE_SOURCE_LINKS(bldLINK_SOURCES)')
+
+install-`'bldCURRENT_PRODUCT: bldCURRENT_PRODUCT.a
+
+bldCURRENT_PRODUCT-clean:
+	rm -f ${OBJS} bldCURRENT_PRODUCT.a ${MANPAGES}
+
+divert(0)
diff --git a/gnu/usr.sbin/sendmail/devtools/M4/UNIX/links.m4 b/gnu/usr.sbin/sendmail/devtools/M4/UNIX/links.m4
new file mode 100644
index 00000000000..5b61eecc7b3
--- /dev/null
+++ b/gnu/usr.sbin/sendmail/devtools/M4/UNIX/links.m4
@@ -0,0 +1,29 @@
+divert(-1)
+#
+# Copyright (c) 1999 Sendmail, Inc. and its suppliers.
+#	All rights reserved.
+#
+# By using this file, you agree to the terms and conditions set
+# forth in the LICENSE file which can be found at the top level of
+# the sendmail distribution.
+#
+#
+#  Definitions for Makefile construction for sendmail
+#
+#	$Sendmail: links.m4,v 8.5 1999/07/25 03:53:08 gshapiro Exp $
+#
+divert(0)dnl
+define(`bldMAKE_SOURCE_LINK',
+`$1: ${SRCDIR}/$1
+	-ln -s ${SRCDIR}/$1 $1'
+)dnl
+define(`bldMAKE_SOURCE_LINKS', 
+`bldFOREACH(`bldMAKE_SOURCE_LINK(', $1)'dnl
+)dnl
+define(`bldMAKE_TARGET_LINKS', 
+`	for i in $2; do \
+		rm -f $$i; \
+		ln -s $1 $$i; \
+	done'
+)dnl
+
diff --git a/gnu/usr.sbin/sendmail/devtools/M4/UNIX/manpage.m4 b/gnu/usr.sbin/sendmail/devtools/M4/UNIX/manpage.m4
new file mode 100644
index 00000000000..f2813473b4f
--- /dev/null
+++ b/gnu/usr.sbin/sendmail/devtools/M4/UNIX/manpage.m4
@@ -0,0 +1,76 @@
+divert(-1)
+#
+# Copyright (c) 1999 Sendmail, Inc. and its suppliers.
+#	All rights reserved.
+#
+# By using this file, you agree to the terms and conditions set
+# forth in the LICENSE file which can be found at the top level of
+# the sendmail distribution.
+#
+#
+#  Definitions for Makefile construction for sendmail
+#
+#	$Sendmail: manpage.m4,v 8.10 1999/10/27 05:17:55 gshapiro Exp $
+#
+divert(0)dnl
+
+define(`bldGET_MAN_SOURCE_NUM',
+`substr($1, eval(len($1) - 1))'dnl
+)dnl
+define(`bldGET_MAN_BASE_NAME',
+`substr($1, 0, eval(len($1) - 2))'dnl
+)dnl
+ifdef(`confNO_MAN_BUILD',, `
+bldPUSH_TARGET(`${MANPAGES}')
+bldPUSH_INSTALL_TARGET(`install-docs')')
+bldLIST_PUSH_ITEM(`bldMAN_PAGES', `bldSOURCES')dnl
+
+MANOWN=	ifdef(`confMANOWN', `confMANOWN', `bin')
+MANGRP=	ifdef(`confMANGRP', `confMANGRP', `bin')
+MANMODE=ifdef(`confMANMODE', `confMANMODE', `444')
+MANROOT=ifdef(`confMANROOT', `confMANROOT', `/usr/share/man/cat')
+MANROOTMAN=ifdef(`confMANROOTMAN', `confMANROOTMAN', `/usr/share/man/man')
+MAN1=	${MANROOT}ifdef(`confMAN1', `confMAN1', `1')
+MAN1MAN=${MANROOTMAN}ifdef(`confMAN1', `confMAN1', `1')
+MAN1EXT=ifdef(`confMAN1EXT', `confMAN1EXT', `1')
+MAN1SRC=ifdef(`confMAN1SRC', `confMAN1SRC', `0')
+MAN3=	${MANROOT}ifdef(`confMAN3', `confMAN3', `3')
+MAN3MAN=${MANROOTMAN}ifdef(`confMAN3', `confMAN3', `3')
+MAN3EXT=ifdef(`confMAN3EXT', `confMAN3EXT', `3')
+MAN3SRC=ifdef(`confMAN3SRC', `confMAN3SRC', `0')
+MAN4=	${MANROOT}ifdef(`confMAN4', `confMAN4', `4')
+MAN4MAN=${MANROOTMAN}ifdef(`confMAN4', `confMAN4', `4')
+MAN4EXT=ifdef(`confMAN4EXT', `confMAN4EXT', `4')
+MAN4SRC=ifdef(`confMAN4SRC', `confMAN4SRC', `0')
+MAN5=	${MANROOT}ifdef(`confMAN5', `confMAN5', `5')
+MAN5MAN=${MANROOTMAN}ifdef(`confMAN5', `confMAN5', `5')
+MAN5EXT=ifdef(`confMAN5EXT', `confMAN5EXT', `5')
+MAN5SRC=ifdef(`confMAN5SRC', `confMAN5SRC', `0')
+MAN8=	${MANROOT}ifdef(`confMAN8', `confMAN8', `8')
+MAN8MAN=${MANROOTMAN}ifdef(`confMAN8', `confMAN8', `8')
+MAN8EXT=ifdef(`confMAN8EXT', `confMAN8EXT', `8')
+MAN8SRC=ifdef(`confMAN8SRC', `confMAN8SRC', `0')
+
+define(`bldMAN_TARGET_NAME', 
+`bldGET_MAN_BASE_NAME($1).${MAN`'bldGET_MAN_SOURCE_NUM($1)`SRC}' 'dnl
+)dnl
+MANPAGES= bldFOREACH(`bldMAN_TARGET_NAME(', `bldMAN_PAGES')
+
+divert(bldTARGETS_SECTION)
+define(`bldMAN_BUILD_CMD',
+`bldGET_MAN_BASE_NAME($1).${MAN`'bldGET_MAN_SOURCE_NUM($1)`SRC}': bldGET_MAN_BASE_NAME($1).bldGET_MAN_SOURCE_NUM($1)
+	${NROFF} ${MANDOC} bldGET_MAN_BASE_NAME($1).bldGET_MAN_SOURCE_NUM($1) > bldGET_MAN_BASE_NAME($1)`.${MAN'bldGET_MAN_SOURCE_NUM($1)`SRC}' || ${CP} bldGET_MAN_BASE_NAME($1)`.${MAN'bldGET_MAN_SOURCE_NUM($1)`SRC}'.dist bldGET_MAN_BASE_NAME($1)`.${MAN'bldGET_MAN_SOURCE_NUM($1)`SRC}''
+
+)dnl
+bldFOREACH(`bldMAN_BUILD_CMD(', `bldMAN_PAGES')
+
+install-docs: ${MANPAGES}
+ifdef(`confNO_MAN_INSTALL', `divert(-1)', `dnl')
+define(`bldMAN_INSTALL_CMD', 
+`	${INSTALL} -c -o ${MANOWN} -g ${MANGRP} -m ${MANMODE} bldGET_MAN_BASE_NAME($1).`${MAN'bldGET_MAN_SOURCE_NUM($1)`SRC}' `${DESTDIR}${MAN'bldGET_MAN_SOURCE_NUM($1)}/bldGET_MAN_BASE_NAME($1)`.${MAN'bldGET_MAN_SOURCE_NUM($1)`EXT}'
+ifdef(`confINSTALL_RAWMAN', 
+`	${INSTALL} -c -o ${MANOWN} -g ${MANGRP} -m ${MANMODE} bldGET_MAN_BASE_NAME($1).`${MAN'bldGET_MAN_SOURCE_NUM($1)`EXT}' `${DESTDIR}${MAN'bldGET_MAN_SOURCE_NUM($1)`MAN}'/bldGET_MAN_BASE_NAME($1)`.${MAN'bldGET_MAN_SOURCE_NUM($1)`EXT}'', `dnl')'
+)dnl
+bldFOREACH(`bldMAN_INSTALL_CMD(', `bldMAN_PAGES')
+ifdef(`confNO_MAN_INSTALL', `divert(0)', `dnl')
+divert(0)
diff --git a/gnu/usr.sbin/sendmail/devtools/M4/depend/AIX.m4 b/gnu/usr.sbin/sendmail/devtools/M4/depend/AIX.m4
new file mode 100644
index 00000000000..af024ad9b04
--- /dev/null
+++ b/gnu/usr.sbin/sendmail/devtools/M4/depend/AIX.m4
@@ -0,0 +1,15 @@
+#	$Sendmail: AIX.m4,v 8.2 1999/05/28 05:54:26 gshapiro Exp $
+depend: ${BEFORE} ${LINKS}
+	@mv Makefile Makefile.old
+	@sed -e '/^# Do not edit or remove this line or anything below it.$$/,$$d' < Makefile.old > Makefile
+	@echo "# Do not edit or remove this line or anything below it." >> Makefile
+	changequote([,])
+	for i in ${SRCS}; \
+	do \
+		${CC} -M -E ${COPTS} $$i > /dev/null; \
+		cat `basename $$i .c`.u >> Makefile ; \
+		rm -f `basename $$i .c`.u ; \
+	done;
+	changequote
+
+#	End of $RCSfile: AIX.m4,v $
diff --git a/gnu/usr.sbin/sendmail/devtools/M4/depend/BSD.m4 b/gnu/usr.sbin/sendmail/devtools/M4/depend/BSD.m4
new file mode 100644
index 00000000000..d06375eea0f
--- /dev/null
+++ b/gnu/usr.sbin/sendmail/devtools/M4/depend/BSD.m4
@@ -0,0 +1,8 @@
+#	$Sendmail: BSD.m4,v 8.6 1999/05/27 22:03:28 peterh Exp $
+depend: ${BEFORE} ${LINKS}
+	@mv Makefile Makefile.old
+	@sed -e '/^# Do not edit or remove this line or anything below it.$$/,$$d' < Makefile.old > Makefile
+	@echo "# Do not edit or remove this line or anything below it." >> Makefile
+	mkdep -a -f Makefile ${COPTS} ${SRCS}
+
+#	End of $RCSfile: BSD.m4,v $
diff --git a/gnu/usr.sbin/sendmail/devtools/M4/depend/CC-M.m4 b/gnu/usr.sbin/sendmail/devtools/M4/depend/CC-M.m4
new file mode 100644
index 00000000000..5d2936280e9
--- /dev/null
+++ b/gnu/usr.sbin/sendmail/devtools/M4/depend/CC-M.m4
@@ -0,0 +1,8 @@
+#	$Sendmail: CC-M.m4,v 8.5 1999/05/27 22:03:28 peterh Exp $
+depend: ${BEFORE} ${LINKS}
+	@mv Makefile Makefile.old
+	@sed -e '/^# Do not edit or remove this line or anything below it.$$/,$$d' < Makefile.old > Makefile
+	@echo "# Do not edit or remove this line or anything below it." >> Makefile
+	${CC} -M ${COPTS} ${SRCS} >> Makefile
+
+#	End of $RCSfile: CC-M.m4,v $
diff --git a/gnu/usr.sbin/sendmail/devtools/M4/depend/NCR.m4 b/gnu/usr.sbin/sendmail/devtools/M4/depend/NCR.m4
new file mode 100644
index 00000000000..bb288d1a897
--- /dev/null
+++ b/gnu/usr.sbin/sendmail/devtools/M4/depend/NCR.m4
@@ -0,0 +1,8 @@
+#	$Sendmail: NCR.m4,v 8.6 1999/05/27 22:03:29 peterh Exp $
+depend: ${BEFORE} ${LINKS}
+	@mv Makefile Makefile.old
+	@sed -e '/^# Do not edit or remove this line or anything below it.$$/,$$d' < Makefile.old > Makefile
+	@echo "# Do not edit or remove this line or anything below it." >> Makefile
+	${CC} -w0 -Hmake ${COPTS} ${SRCS} >> Makefile
+
+#	End of $RCSfile: NCR.m4,v $
diff --git a/gnu/usr.sbin/sendmail/devtools/M4/depend/Solaris.m4 b/gnu/usr.sbin/sendmail/devtools/M4/depend/Solaris.m4
new file mode 100644
index 00000000000..847c9d59a34
--- /dev/null
+++ b/gnu/usr.sbin/sendmail/devtools/M4/depend/Solaris.m4
@@ -0,0 +1,8 @@
+#	$Sendmail: Solaris.m4,v 8.4 1999/05/27 22:03:29 peterh Exp $
+depend: ${BEFORE} ${LINKS}
+	@mv Makefile Makefile.old
+	@sed -e '/^# Do not edit or remove this line or anything below it.$$/,$$d' < Makefile.old > Makefile
+	@echo "# Do not edit or remove this line or anything below it." >> Makefile
+	${CC} -xM ${COPTS} ${SRCS} >> Makefile
+
+#	End of $RCSfile: Solaris.m4,v $
diff --git a/gnu/usr.sbin/sendmail/devtools/M4/depend/X11.m4 b/gnu/usr.sbin/sendmail/devtools/M4/depend/X11.m4
new file mode 100644
index 00000000000..40c3ab85c8d
--- /dev/null
+++ b/gnu/usr.sbin/sendmail/devtools/M4/depend/X11.m4
@@ -0,0 +1,5 @@
+#	$Sendmail: X11.m4,v 8.4 1999/05/27 22:03:29 peterh Exp $
+depend: ${BEFORE} ${LINKS}
+	makedepend -- ${COPTS} -- ${SRCS}
+
+#	End of $RCSfile: X11.m4,v $
diff --git a/gnu/usr.sbin/sendmail/devtools/M4/depend/generic.m4 b/gnu/usr.sbin/sendmail/devtools/M4/depend/generic.m4
new file mode 100644
index 00000000000..f3fa117a4fe
--- /dev/null
+++ b/gnu/usr.sbin/sendmail/devtools/M4/depend/generic.m4
@@ -0,0 +1,6 @@
+#	$Sendmail: generic.m4,v 8.5 1999/05/24 18:38:33 rand Exp $
+# dependencies
+
+# give a null "depend" list so that the startup script will work
+depend:
+#	End of $RCSfile: generic.m4,v $
diff --git a/gnu/usr.sbin/sendmail/devtools/M4/header.m4 b/gnu/usr.sbin/sendmail/devtools/M4/header.m4
new file mode 100644
index 00000000000..e3b6c9cc90b
--- /dev/null
+++ b/gnu/usr.sbin/sendmail/devtools/M4/header.m4
@@ -0,0 +1,35 @@
+#
+# Copyright (c) 1998, 1999 Sendmail, Inc. and its suppliers.
+#	All rights reserved.
+#
+# By using this file, you agree to the terms and conditions set
+# forth in the LICENSE file which can be found at the top level of
+# the sendmail distribution.
+#
+#
+#  Definitions for Makefile construction for sendmail
+#
+#	$Sendmail: header.m4,v 8.26 1999/08/09 18:57:22 gshapiro Exp $
+#
+changecom(^A)
+undefine(`format')
+undefine(`hpux')
+undefine(`unix')
+ifdef(`pushdef', `',
+	`errprint(`You need a newer version of M4, at least as new as
+System V or GNU')
+	include(NoSuchFile)')
+define(`confCC', `cc')
+define(`confSHELL', `/bin/sh')
+define(`confBEFORE', `')
+define(`confLIBDIRS', `')
+define(`confINCDIRS', `')
+define(`confLIBSEARCH', `db bind resolv 44bsd')
+define(`confLIBSEARCHPATH', `/lib /usr/lib /usr/shlib')
+define(`confSITECONFIG', `site.config')
+define(`confBUILDBIN', `${SRCDIR}/devtools/bin')
+define(`confRANLIB', `echo')
+define(`PUSHDIVERT', `pushdef(`__D__', divnum)divert($1)')
+define(`POPDIVERT', `divert(__D__)popdef(`__D__')')
+define(`APPENDDEF', `define(`$1', ifdef(`$1', `$1 $2', `$2'))')
+define(`PREPENDDEF', `define(`$1', ifdef(`$1', `$2 $1', `$2'))')
diff --git a/gnu/usr.sbin/sendmail/devtools/M4/list.m4 b/gnu/usr.sbin/sendmail/devtools/M4/list.m4
new file mode 100644
index 00000000000..fb072c78c1e
--- /dev/null
+++ b/gnu/usr.sbin/sendmail/devtools/M4/list.m4
@@ -0,0 +1,26 @@
+divert(-1)
+#
+# Copyright (c) 1999 Sendmail, Inc. and its suppliers.
+#	All rights reserved.
+#
+# By using this file, you agree to the terms and conditions set
+# forth in the LICENSE file which can be found at the top level of
+# the sendmail distribution.
+#
+#
+#  Definitions for Makefile construction for sendmail
+#
+#	$Sendmail: list.m4,v 8.3 1999/07/15 22:46:05 rand Exp $
+#
+divert(0)dnl
+define(`bldLIST_PUSH_ITEM',
+`define(`$1', ifdef(`$1', `$1 $2 ', `$2 '))'
+)dnl
+define(`bldFOREACH',
+`$1substr($2, `0', index($2, ` ')))`'ifelse(index($2, ` '), eval(len($2)-1),  , `bldFOREACH(`$1', substr($2, index($2, ` ')))')'dnl
+)dnl 
+
+define(`bldADD_PATH', `$1/$2 ')dnl
+define(`bldADD_PATHS',
+`bldFOREACH(`bldADD_PATH(`$1',', $2)'dnl
+)dnl
diff --git a/gnu/usr.sbin/sendmail/devtools/M4/string.m4 b/gnu/usr.sbin/sendmail/devtools/M4/string.m4
new file mode 100644
index 00000000000..866061b4ddc
--- /dev/null
+++ b/gnu/usr.sbin/sendmail/devtools/M4/string.m4
@@ -0,0 +1,18 @@
+divert(-1)
+#
+# Copyright (c) 1999 Sendmail, Inc. and its suppliers.
+#	All rights reserved.
+#
+# By using this file, you agree to the terms and conditions set
+# forth in the LICENSE file which can be found at the top level of
+# the sendmail distribution.
+#
+#
+#  Definitions for Makefile construction for sendmail
+#
+#	$Sendmail: string.m4,v 8.2 1999/05/13 16:16:33 gshapiro Exp $
+#
+divert(0)dnl
+define(`bldRINDEX',
+`ifelse(index($1, $2), `-1', `-1', `eval(index($1, $2) + bldRINDEX(substr($1, eval(index($1, $2) + 1)), $2) + 1)')'dnl
+)dnl
diff --git a/gnu/usr.sbin/sendmail/devtools/M4/subst_ext.m4 b/gnu/usr.sbin/sendmail/devtools/M4/subst_ext.m4
new file mode 100644
index 00000000000..24cf311149b
--- /dev/null
+++ b/gnu/usr.sbin/sendmail/devtools/M4/subst_ext.m4
@@ -0,0 +1,30 @@
+divert(-1)
+#
+# Copyright (c) 1999 Sendmail, Inc. and its suppliers.
+#	All rights reserved.
+#
+# By using this file, you agree to the terms and conditions set
+# forth in the LICENSE file which can be found at the top level of
+# the sendmail distribution.
+#
+#
+#  Definitions for Makefile construction for sendmail
+#
+#	$Sendmail: subst_ext.m4,v 8.3 1999/05/24 18:29:46 rand Exp $
+#
+divert(0)dnl
+define(`bldSUBST_EXTENSION',
+`substr($2, 0, bldRINDEX($2, `.'))`'.$1 'dnl
+)dnl
+define(`bldSUBST_EXTENSIONS',
+`bldFOREACH(`bldSUBST_EXTENSION(`$1',', $2)'dnl
+)dnl
+define(`bldREMOVE_COMMAS',
+`$1 ifelse($#, 1, , `bldREMOVE_COMMAS(shift($@))')'dnl
+)dnl
+
+define(`bldADD_EXTENSION', `$2.$1 ')dnl
+define(`bldADD_EXTENSIONS',
+`bldFOREACH(`bldADD_EXTENSION(`$1',', $2)'dnl
+)dnl
+
diff --git a/gnu/usr.sbin/sendmail/devtools/M4/switch.m4 b/gnu/usr.sbin/sendmail/devtools/M4/switch.m4
new file mode 100644
index 00000000000..1be998a6013
--- /dev/null
+++ b/gnu/usr.sbin/sendmail/devtools/M4/switch.m4
@@ -0,0 +1,71 @@
+divert(-1)
+#
+# Copyright (c) 1999 Sendmail, Inc. and its suppliers.
+#	All rights reserved.
+#
+# By using this file, you agree to the terms and conditions set
+# forth in the LICENSE file which can be found at the top level of
+# the sendmail distribution.
+#
+#
+#  Definitions for Makefile construction for sendmail
+#
+#	$Sendmail: switch.m4,v 8.13 1999/09/07 17:21:50 ca Exp $
+#
+divert(0)dnl
+include(confBUILDTOOLSDIR`/M4/string.m4')dnl
+include(confBUILDTOOLSDIR`/M4/list.m4')dnl
+include(confBUILDTOOLSDIR`/M4/subst_ext.m4')dnl
+define(`bldDEPENDENCY_SECTION', `3')dnl
+define(`bldTARGETS_SECTION', `6')dnl
+define(`bldPUSH_TARGET',
+	`bldLIST_PUSH_ITEM(`bldTARGETS', `$1')'dnl
+)dnl
+
+define(`bldPUSH_INSTALL_TARGET',
+	`bldLIST_PUSH_ITEM(`bldINSTALL_TARGETS', `$1')'dnl
+)dnl
+
+define(`bldPUSH_CLEAN_TARGET',
+	`bldLIST_PUSH_ITEM(`bldCLEAN_TARGETS', `$1')'dnl
+)dnl
+
+define(`bldPUSH_ALL_SRCS',
+	`bldLIST_PUSH_ITEM(`bldALL_SRCS', `$1')'dnl
+)dnl
+
+define(`bldPUSH_SMDEPLIB',
+	`bldLIST_PUSH_ITEM(`bldSMDEPLIBS', `$1')'dnl
+)dnl
+
+define(`bldPUSH_SMLIB',
+	`bldPUSH_TARGET(`../lib$1/lib$1.a')
+bldPUSH_SMDEPLIB(`../lib$1/lib$1.a')
+PREPENDDEF(`confLIBDIRS', `-L../lib$1')
+PREPENDDEF(`confLIBS', `-l$1')
+divert(bldTARGETS_SECTION)
+../lib$1/lib$1.a:
+	(cd ${SRCDIR}/lib$1; sh Build ${SENDMAIL_BUILD_FLAGS})
+divert
+')dnl
+
+define(`bldPUSH_STRIP_TARGET',
+	`bldLIST_PUSH_ITEM(`bldSTRIP_TARGETS', `$1')'dnl
+)dnl
+
+define(`bldPRODUCT_START',
+`define(`bldCURRENT_PRODUCT', `$2')dnl
+define(`bldCURRENT_PRD', translit(`$2', `.', `_'))dnl
+define(`bldPRODUCT_TYPE', `$1')dnl'
+)dnl
+
+define(`bldM4_TYPE_DIR',ifdef(`confNT', `NT', ``UNIX''))dnl
+
+define(`bldPRODUCT_END',
+`include(confBUILDTOOLSDIR`/M4/'bldM4_TYPE_DIR`/'bldPRODUCT_TYPE`.m4')'
+)dnl
+
+define(`bldFINISH', 
+ifdef(`bldDONT_INCLUDE_ALL', ,``include(confBUILDTOOLSDIR`/M4/'bldM4_TYPE_DIR`/all.m4')'')dnl
+undivert(bldTARGETS_SECTION)dnl
+)dnl