initial import of NetBSD tree

1 files changed, 80 insertions, 0 deletions

diff --git a/lib/libc/arch/m68k/string/bzero.S b/lib/libc/arch/m68k/string/bzero.S
new file mode 100644
index 00000000000..c9822440bb2
--- /dev/null
+++ b/lib/libc/arch/m68k/string/bzero.S
@@ -0,0 +1,80 @@
+/*-
+ * Copyright (c) 1990 The Regents of the University of California.
+ * All rights reserved.
+ *
+ * This code is derived from software contributed to Berkeley by
+ * the Systems Programming Group of the University of Utah Computer
+ * Science Department.
+ *
+ * Redistribution and use in source and binary forms, with or without
+ * modification, are permitted provided that the following conditions
+ * are met:
+ * 1. Redistributions of source code must retain the above copyright
+ *    notice, this list of conditions and the following disclaimer.
+ * 2. Redistributions in binary form must reproduce the above copyright
+ *    notice, this list of conditions and the following disclaimer in the
+ *    documentation and/or other materials provided with the distribution.
+ * 3. All advertising materials mentioning features or use of this software
+ *    must display the following acknowledgement:
+ *	This product includes software developed by the University of
+ *	California, Berkeley and its contributors.
+ * 4. Neither the name of the University nor the names of its contributors
+ *    may be used to endorse or promote products derived from this software
+ *    without specific prior written permission.
+ *
+ * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
+ * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
+ * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
+ * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
+ * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
+ * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
+ * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
+ * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
+ * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
+ * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
+ * SUCH DAMAGE.
+ */
+
+#if defined(LIBC_SCCS) && !defined(lint)
+	.text
+	/*.asciz "from: @(#)bzero.s	5.1 (Berkeley) 5/12/90"*/
+	.asciz "$Id: bzero.S,v 1.1 1995/10/18 08:41:31 deraadt Exp $"
+#endif /* LIBC_SCCS and not lint */
+
+#include "DEFS.h"
+
+/*
+ * This is probably not the best we can do, but it is still much
+ * faster than the C version in the portable gen directory.
+ *
+ * Things that might help:
+ *	- unroll the longword loop (might not be good for a 68020)
+ *	- longword, as opposed to word, align when possible (only on the 68020)
+ *	- use nested DBcc instructions or use one and limit size to 64K
+ */
+ENTRY(bzero)
+	movl	sp@(4),a0		| destination
+	movl	sp@(8),d0		| count
+	beq	bzdone			| nothing to do
+	movl	a0,d1
+	btst	#0,d1			| address odd?
+	beq	bzeven			| no, skip alignment
+	clrb	a0@+			| yes, clear a byte
+	subql	#1,d0			| adjust count
+	beq	bzdone			| if zero, all done
+bzeven:
+	movl	d0,d1
+	lsrl	#2,d1			| convert to longword count
+	beq	bzbloop			| no longwords, skip loop
+bzlloop:
+	clrl	a0@+			| clear a longword
+	subql	#1,d1			| adjust count
+	bne	bzlloop			| still more, keep going
+	andl	#3,d0			| what remains
+	beq	bzdone			| nothing, all done
+bzbloop:
+	clrb	a0@+			| clear a byte
+	subql	#1,d0			| adjust count
+	bne	bzbloop			| still more, keep going
+bzdone:
+	rts