1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
|
/* $OpenBSD: fixunsdfsi.S,v 1.3 2003/07/21 18:43:55 jason Exp $ */
/* $NetBSD: fixunsdfsi.S,v 1.3 2000/07/25 04:26:12 mycroft Exp $ */
/*
* Copyright (c) 1992, 1993
* The Regents of the University of California. All rights reserved.
*
* This software was developed by the Computer Systems Engineering group
* at Lawrence Berkeley Laboratory under DARPA contract BG 91-66 and
* contributed to Berkeley.
*
* Redistribution and use in source and binary forms, with or without
* modification, are permitted provided that the following conditions
* are met:
* 1. Redistributions of source code must retain the above copyright
* notice, this list of conditions and the following disclaimer.
* 2. Redistributions in binary form must reproduce the above copyright
* notice, this list of conditions and the following disclaimer in the
* documentation and/or other materials provided with the distribution.
* 3. Neither the name of the University nor the names of its contributors
* may be used to endorse or promote products derived from this software
* without specific prior written permission.
*
* THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
* ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
* IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
* ARE DISCLAIMED. IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
* FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
* DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
* OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
* HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
* LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
* OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
* SUCH DAMAGE.
*/
#include <machine/asm.h>
#define _LOCORE
#include <machine/frame.h>
/*
* Convert double to unsigned integer (for gcc).
*
* I have made the output for NaN agree with the Sun compiler, not
* that it really matters, by using `fbul,a'.
*/
.align 8
Lbigd:
.word 0x43e00000 ! .double 2^63
.word 0 ! (who me, not trust the assembler?)
Lbigf:
.word 0x5f000000 ! .float 2^63
/*
*unsigned long __dtoul(double):
* double -> unsigned long
*/
ENTRY(__dtoul)
sub %sp, 16, %sp
std %f2, [%sp + 64 + BIAS + 8]
#ifdef PIC
PICCY_SET(Lbigd, %g1, %o0)
ldd [%g1], %f2
#else
sethi %hi(Lbigd), %g1
ldd [%g1 + %lo(Lbigd)], %f2
#endif
fcmped %f0, %f2 ! d < 2^63, or NaN, or -Inf?
nop ! (fpop2 delay)
fbul,a 1f ! if so, use fdtoi to convert to int
fdtox %f0, %f0 ! (this includes negatives!)
! d does not fit in an int, so subtract 2^63, convert,
! and add 2^63 again (sigh). Just hope the intermediate
! fits (if not, the result is undefined anyway).
fsubd %f0, %f2, %f0 ! d -= 2^63
fdtox %f0, %f0 ! convert to int
std %f0, [%sp + 64 + BIAS] ! move into return reg
ldx [%sp + 64 + BIAS], %o0
sethi %hi(0x80000000), %o1
sllx %o1, 32, %o1
add %o0, %o1, %o0 ! add 2^63
ldd [%sp + 64 + BIAS + 8], %f2
retl
add %sp, 16, %sp
1:
std %f0, [%sp + 64 + BIAS] ! return result
ldx [%sp + 64 + BIAS], %o0
ldd [%sp + 64 + BIAS + 8], %f2
retl
add %sp, 16, %sp
/*
*unsigned long __ftoul(float):
* float -> unsigned long
*/
ENTRY(__ftoul)
sub %sp, 16, %sp
st %f1, [%sp + 64 + BIAS + 8]
st %f2, [%sp + 64 + BIAS + 12]
#ifdef PIC
PICCY_SET(Lbigf, %g1, %o0)
ld [%g1], %f2
#else
sethi %hi(Lbigf), %g1
ld [%g1 + %lo(Lbigf)], %f2
#endif
fcmpes %f0, %f2 ! d < 2^63, or NaN, or -Inf?
nop ! (fpop2 delay)
fbul,a 1f ! if so, use fdtoi to convert to int
fstox %f0, %f0 ! (this includes negatives!)
! d does not fit in an int, so subtract 2^63, convert,
! and add 2^63 again (sigh). Just hope the intermediate
! fits (if not, the result is undefined anyway).
fsubs %f0, %f2, %f0 ! d -= 2^63
fstox %f0, %f0 ! convert to int
std %f0, [%sp + 64 + BIAS] ! move into return reg
ldx [%sp + 64 + BIAS], %o0
sethi %hi(0x80000000), %o1
sllx %o1, 32, %o1
add %o0, %o1, %o0 ! add 2^63
ld [%sp + 64 + BIAS + 8], %f1
ld [%sp + 64 + BIAS + 12], %f2
retl
add %sp, 16, %sp
1:
std %f0, [%sp + 64 + BIAS] ! return result
ldx [%sp + 64 + BIAS], %o0
ld [%sp + 64 + BIAS + 8], %f1
ld [%sp + 64 + BIAS + 12], %f2
retl
add %sp, 16, %sp
|
