1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
|
/* $OpenBSD: rfork_thread.S,v 1.3 2009/09/24 19:47:35 guenther Exp $ */
/*-
* Copyright (c) 2000 Peter Wemm <peter@FreeBSD.org>
* Copyright (c) 2003 Alan L. Cox <alc@cs.rice.edu>
* All rights reserved.
*
* Redistribution and use in source and binary forms, with or without
* modification, are permitted provided that the following conditions
* are met:
* 1. Redistributions of source code must retain the above copyright
* notice, this list of conditions and the following disclaimer.
* 2. Redistributions in binary form must reproduce the above copyright
* notice, this list of conditions and the following disclaimer in the
* documentation and/or other materials provided with the distribution.
*
* THIS SOFTWARE IS PROVIDED BY THE AUTHOR AND CONTRIBUTORS ``AS IS'' AND
* ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
* IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
* ARE DISCLAIMED. IN NO EVENT SHALL THE AUTHOR OR CONTRIBUTORS BE LIABLE
* FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
* DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
* OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
* HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
* LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
* OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
* SUCH DAMAGE.
*/
#include <machine/asm.h>
#if 0
__FBSDID("$FreeBSD: /repoman/r/ncvs/src/lib/libc/amd64/gen/rfork_thread.S,v 1.1 2003/10/13 20:32:33 alc Exp $");
#endif
/*
* With thanks to John Dyson for the original version of this.
*/
#include "../../../libc/arch/amd64/SYS.h"
/*
* %edi %rsi %rdx %rcx
* rfork_thread(flags, stack_addr, start_fnc, start_arg);
*
* flags: Flags to rfork system call. See rfork(2).
* stack_addr: Top of stack for thread.
* start_fnc: Address of thread function to call in child.
* start_arg: Argument to pass to the thread function in child.
*/
ENTRY(rfork_thread)
pushq %rbx
pushq %r12
movq %rdx, %rbx
movq %rcx, %r12
/*
* Prepare and execute the thread creation syscall
*/
movq $SYS_rfork, %rax
int $0x80
jb 2f
/*
* Check to see if we are in the parent or child
*/
cmpl $0, %edx
jnz 1f
popq %r12
popq %rbx
ret
/*
* If we are in the child (new thread), then
* set-up the call to the internal subroutine. If it
* returns, then call __exit.
*/
1:
movq %rsi, %rsp
movq %r12, %rdi
call *%rbx
movl %eax, %edi
/*
* Exit system call
*/
movq $SYS_threxit, %rax
int $0x80
/*
* Branch here if the thread creation fails:
*/
2:
popq %r12
popq %rbx
#ifdef PIC
movq PIC_GOT(CERROR), %rcx
jmp *%rcx
#else
jmp CERROR
#endif
|
