blob: a55a65386b7b918d18b52eec1a395c57d2e3379c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
|
/* $OpenBSD: ld.script,v 1.11 2003/01/31 23:42:28 mickey Exp $ */
OUTPUT_FORMAT("elf32-hppa")
OUTPUT_ARCH(hppa)
ENTRY($start)
SECTIONS
{
. = + SIZEOF_HEADERS;
.text :
{
kernel_text = . ;
*(.text) *(.text.*)
*(.reginfo)
*(.init)
*(.stub)
/* .gnu.warning sections are handled specially by elf32.em. */
*(.gnu.warning)
. = ALIGN(4096);
etext = ABSOLUTE(.);
} = 0x08000240 /* nop filled */
.rodata :
{
__rodata_start = .;
*(.rodata) *(.rodata1)
__unwind_start = .;
*(.PARISC.unwind)
__unwind_end = .;
__rodata_end = .;
} = 0
. = 0x400000;
__data_start = ABSOLUTE(.);
.data :
{
$global$ = . ;
. += 4;
*(.data)
CONSTRUCTORS
. = ALIGN(4096);
edata = ABSOLUTE(.);
} = 0
.ctors : { *(.ctors) }
.dtors : { *(.dtors) }
__bss_start = .;
/* .sbss : { *(.sbss) *(.scommon) } */
.bss :
{
*(.dynbss) *(.bss)
*(COMMON) *($COMMON$)
. = ALIGN(4096);
}
end = ABSOLUTE(.);
}
|
