1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
|
/* $OpenBSD: icu.s,v 1.9 1997/07/23 06:58:34 denny Exp $ */
/* $NetBSD: icu.s,v 1.45 1996/01/07 03:59:34 mycroft Exp $ */
/*-
* Copyright (c) 1993, 1994, 1995 Charles M. Hannum. All rights reserved.
*
* Redistribution and use in source and binary forms, with or without
* modification, are permitted provided that the following conditions
* are met:
* 1. Redistributions of source code must retain the above copyright
* notice, this list of conditions and the following disclaimer.
* 2. Redistributions in binary form must reproduce the above copyright
* notice, this list of conditions and the following disclaimer in the
* documentation and/or other materials provided with the distribution.
* 3. All advertising materials mentioning features or use of this software
* must display the following acknowledgement:
* This product includes software developed by Charles M. Hannum.
* 4. The name of the author may not be used to endorse or promote products
* derived from this software without specific prior written permission.
*
* THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
* IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
* OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
* IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
* INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
* NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
* DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
* THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
* (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
* THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
*/
#include <net/netisr.h>
.data
.globl _imen,_cpl,_ipending,_astpending,_netisr
_imen:
.long 0xffff # interrupt mask enable (all off)
.text
#if defined(PROF) || defined(GPROF)
.globl _splhigh, _splx
ALIGN_TEXT
_splhigh:
movl $-1,%eax
xchgl %eax,_cpl
ret
ALIGN_TEXT
_splx:
movl 4(%esp),%eax
movl %eax,_cpl
testl %eax,%eax
jnz _Xspllower
ret
#endif /* PROF || GPROF */
/*
* Process pending interrupts.
*
* Important registers:
* ebx - cpl
* esi - address to resume loop at
* edi - scratch for Xsoftnet
*/
IDTVEC(spllower)
pushl %ebx
pushl %esi
pushl %edi
movl _cpl,%ebx # save priority
movl $1f,%esi # address to resume loop at
1: movl %ebx,%eax
notl %eax
andl _ipending,%eax
jz 2f
bsfl %eax,%eax
btrl %eax,_ipending
jnc 1b
jmp *_Xrecurse(,%eax,4)
2: popl %edi
popl %esi
popl %ebx
ret
/*
* Handle return from interrupt after device handler finishes.
*
* Important registers:
* ebx - cpl to restore
* esi - address to resume loop at
* edi - scratch for Xsoftnet
*/
IDTVEC(doreti)
popl %ebx # get previous priority
movl %ebx,_cpl
movl $1f,%esi # address to resume loop at
1: movl %ebx,%eax
notl %eax
andl _ipending,%eax
jz 2f
bsfl %eax,%eax # slow, but not worth optimizing
btrl %eax,_ipending
jnc 1b # some intr cleared the in-memory bit
cli
jmp *_Xresume(,%eax,4)
2: /* Check for ASTs on exit to user mode. */
cli
cmpb $0,_astpending
je 3f
testb $SEL_RPL,TF_CS(%esp)
#ifdef VM86
jnz 4f
testl $PSL_VM,TF_EFLAGS(%esp)
#endif
jz 3f
4: movb $0,_astpending
sti
/* Pushed T_ASTFLT into tf_trapno on entry. */
call _trap
jmp 2b
3: INTRFASTEXIT
/*
* Soft interrupt handlers
*/
#include "pccom.h"
IDTVEC(softtty)
#if NPCCOM > 0
leal SIR_TTYMASK(%ebx),%eax
movl %eax,_cpl
call _comsoft
movl %ebx,_cpl
#endif
jmp %esi
#define DONET(s, c) \
.globl c ;\
testl $(1 << s),%edi ;\
jz 1f ;\
call c ;\
1:
IDTVEC(softnet)
leal SIR_NETMASK(%ebx),%eax
movl %eax,_cpl
xorl %edi,%edi
xchgl _netisr,%edi
#ifdef INET
#include "ether.h"
#if NETHER > 0
DONET(NETISR_ARP, _arpintr)
#endif
DONET(NETISR_IP, _ipintr)
#endif
#ifdef NETATALK
DONET(NETISR_ATALK, _atintr)
#endif
#ifdef IMP
DONET(NETISR_IMP, _impintr)
#endif
#ifdef IPX
DONET(NETISR_IPX, _ipxintr)
#endif
#ifdef NS
DONET(NETISR_NS, _nsintr)
#endif
#ifdef ISO
DONET(NETISR_ISO, _clnlintr)
#endif
#ifdef CCITT
DONET(NETISR_CCITT, _ccittintr)
#endif
#ifdef NATM
DONET(NETISR_NATM, _natmintr)
#endif
#include "ppp.h"
#if NPPP > 0
DONET(NETISR_PPP, _pppintr)
#endif
movl %ebx,_cpl
jmp %esi
IDTVEC(softclock)
leal SIR_CLOCKMASK(%ebx),%eax
movl %eax,_cpl
call _softclock
movl %ebx,_cpl
jmp %esi
|
