1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
|
/* $OpenBSD: biosdisk.S,v 1.13 1997/07/30 19:40:56 flipk Exp $ */
/*
* Copyright (c) 1997 Michael Shalayeff
* All rights reserved.
*
* Redistribution and use in source and binary forms, with or without
* modification, are permitted provided that the following conditions
* are met:
* 1. Redistributions of source code must retain the above copyright
* notice, this list of conditions and the following disclaimer.
* 2. Redistributions in binary form must reproduce the above copyright
* notice, this list of conditions and the following disclaimer in the
* documentation and/or other materials provided with the distribution.
* 3. All advertising materials mentioning features or use of this software
* must display the following acknowledgement:
* This product includes software developed by Michael Shalayeff.
* 4. The name of the author may not be used to endorse or promote products
* derived from this software without specific prior written permission.
*
* THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
* IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
* WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
* ARE DISCLAIMED. IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
* FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
* DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
* OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
* HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
* LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
* OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
* SUCH DAMAGE.
*
*/
#include <machine/asm.h>
#define _LOCORE
#include <machine/biosvar.h>
#include "debug_md.h"
#undef _LOCORE
#include <assym.h>
.globl _C_LABEL(errno) /* XXX used for bios errors */
.globl _C_LABEL(BIOS_regs)
/*
* int biosread(dev,cyl,head,sect,nsect,buf)
* read number of sectors from disk
*/
ENTRY(biosread)
pushl %ebp
movl %esp, %ebp
pushl %ecx
pushl %ebx
pushl %edi
pushl %es
movb 8(%ebp), %dl # device
movw 12(%ebp), %cx
xchgb %ch, %cl # cylinder; the highest 2 bits of cyl is in %cl
rorb $2, %cl
movb 16(%ebp), %dh # head
movb 20(%ebp), %al
orb %al, %cl
incb %cl # sector; sec starts from 1, not 0
movb $0x2, %ah # subfunction
movb 24(%ebp), %al # number of sectors
movl 28(%ebp), %ebx # offset
movl %ebx, %edi # split off for seg:off pair
andl $0xf, %ebx # atomic read for up to 64k
shrl $4, %edi
movl %edi, _C_LABEL(BIOS_regs)+biosr_es
DOINT(0x13)
movb $0, %al
jnc 1f
movb %ah, %al
1:
movzbl %al, %eax # return value in %ax
popl %es
popl %edi
popl %ebx
popl %ecx
popl %ebp
ret
ENTRY(bioswrite)
movl $1, %eax
ret
/*
*
* u_int16_t biosdinfo(): return a word that represents the
* max number of sectors and heads and drives for this device
*
*/
ENTRY(biosdinfo)
pushl %ebp
movl %esp, %ebp
pushl %ebx
pushl %ecx
movb 8(%ebp), %dl # drive #
movb $0x08, %ah # ask for disk info
DOINT(0x13)
movb $1, %ah # max head
movb $18, %al # max sector
jc 1f
/* form a word w/ nhead/nsect packed */
movb %dh, %ah # max head
andb $0x3f, %cl # mask of cylinder gunk
movb %cl, %al # max sector (and # sectors)
1:
popl %ecx
popl %ebx
popl %ebp
ret
/*
*
* biosdreset(): reset disk system
*
*/
ENTRY(biosdreset)
pushl %ebx
pushl %ecx
movb $0x00, %ah # reset disk system
movb 8(%ebp), %dl # drive #
DOINT(0x13)
popl %ecx
popl %ebx
ret
/*
* int EDDcheck(dev)
* check the features supported by the bios for the drive
*/
ENTRY(EDDcheck)
pushl %ebp
movl %esp, %ebp
pushl %ecx
pushl %ebx
movb $0x44, %ah
movw $0x55aa, %bx
movl 8(%ebp), %edx
DOINT(0x13)
movl $-1, %eax
jc 1f
cmpw $0xaa55, %bx
jne 1f
xorl %eax, %eax
movw %cx, %ax /* API support bitmap */
1:
popl %ebx
popl %ecx
popl %ebp
ret
.data
ddp: .byte 0x10 # size of packet
.byte 0 # reserved
.word 0 # # of blocks to transfer
.long 0 # address to read/write to
.long 0,0 # start to read here
.text
/*
* int EDDread(dev,abs_sect,nsect,buf)
* read nsect starting on absolute sector #abs_sect into buf
*/
ENTRY(EDDread)
pushl %ebp
movl %esp, %ebp
pushl %ecx
pushl %ebx
pushl %esi
movl 8(%ebp), %edx /* drive */
movl ddp, %esi
movl 20(%ebp), %eax /* nblks */
movw %ax, 2(%esi)
movl 12(%ebp), %eax /* abs starting sector */
movl %eax, 8(%esi)
movl 16(%ebp), %eax
movl %eax, 12(%esi)
movl 24(%ebp), %eax /* buffer */
movl %eax, 4(%esi)
movb $0x42, %ah
DOINT(0x13)
jnc 1f
xorl %eax, %eax
1: movzbl %ah, %eax
movl %eax, _C_LABEL(errno)
movw 2(%esi), %ax /* return number of blocks read ok */
popl %esi
popl %ebx
popl %ecx
popl %ebp
ret
/*
* int EDDwrite(dev,abs_sect,nsect,buf)
* read nsect starting on absolute sector #abs_sect into buf
*/
ENTRY(EDDwrite)
movl $19, _C_LABEL(errno)
movl $0, %eax
ret
|
