1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
|
/* $OpenBSD: biosdisk.S,v 1.2 1997/03/31 03:12:11 weingart Exp $ */
/*
* Ported to boot 386BSD by Julian Elischer (julian@tfs.com) Sept 1992
*
* Mach Operating System
* Copyright (c) 1992, 1991 Carnegie Mellon University
* All Rights Reserved.
*
* Permission to use, copy, modify and distribute this software and its
* documentation is hereby granted, provided that both the copyright
* notice and this permission notice appear in all copies of the
* software, derivative works or modified versions, and any portions
* thereof, and that both notices appear in supporting documentation.
*
* CARNEGIE MELLON ALLOWS FREE USE OF THIS SOFTWARE IN ITS "AS IS"
* CONDITION. CARNEGIE MELLON DISCLAIMS ANY LIABILITY OF ANY KIND FOR
* ANY DAMAGES WHATSOEVER RESULTING FROM THE USE OF THIS SOFTWARE.
*
* Carnegie Mellon requests users of this software to return to
*
* Software Distribution Coordinator or Software.Distribution@CS.CMU.EDU
* School of Computer Science
* Carnegie Mellon University
* Pittsburgh PA 15213-3890
*
* any improvements or extensions that they make and grant Carnegie Mellon
* the rights to redistribute these changes.
*/
/*
Copyright 1988, 1989, 1990, 1991, 1992
by Intel Corporation, Santa Clara, California.
All Rights Reserved
Permission to use, copy, modify, and distribute this software and
its documentation for any purpose and without fee is hereby
granted, provided that the above copyright notice appears in all
copies and that both the copyright notice and this permission notice
appear in supporting documentation, and that the name of Intel
not be used in advertising or publicity pertaining to distribution
of the software without specific, written prior permission.
INTEL DISCLAIMS ALL WARRANTIES WITH REGARD TO THIS SOFTWARE
INCLUDING ALL IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS,
IN NO EVENT SHALL INTEL BE LIABLE FOR ANY SPECIAL, INDIRECT, OR
CONSEQUENTIAL DAMAGES OR ANY DAMAGES WHATSOEVER RESULTING FROM
LOSS OF USE, DATA OR PROFITS, WHETHER IN ACTION OF CONTRACT,
NEGLIGENCE, OR OTHER TORTIOUS ACTION, ARISING OUT OF OR IN CONNECTION
WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.
*/
#include <machine/asm.h>
#define addr32 .byte 0x67
#define data32 .byte 0x66
/*
# BIOS call "INT 0x13 Function 0x2" to read sectors from disk into memory
# Call with %ah = 0x2
# %al = number of sectors
# %ch = cylinder
# %cl = sector
# %dh = head
# %dl = drive (0x80 for hard disk, 0x0 for floppy disk)
# %es:%bx = segment:offset of buffer
# Return:
# %al = 0x0 on success; err code on failure
*/
ENTRY(biosread)
pushl %ebp
movl %esp, %ebp
pushl %ebx
pushl %esi
pushl %edi
push %es
movb 8(%ebp), %dl # device
movw 12(%ebp), %cx
xchgb %ch, %cl # cylinder; the highest 2 bits of cyl is in %cl
rorb $2, %cl
movb 16(%ebp), %dh # head
movb 20(%ebp), %al
orb %al, %cl
incb %cl # sector; sec starts from 1, not 0
movb $0x2, %ah # subfunction
movb 24(%ebp), %al # number of sectors
movl %eax, %esi # save this against mode switch
movl 28(%ebp), %ebx # offset
# prot_to_real will set %es to BOOTSEG
# Which means %cs == %es.
# XXX - This hoses things severly. Better
# recoup %es to point to the base of the given
# buffer, and let %bx be the index into it,
# that way we can read a max of 64K give or
# take 15 bytes anyways.
# Save %es in %edi
movl %ebx, %eax
shrl $4, %eax
movl %eax, %edi
andl $0xF, %ebx
call _C_LABEL(prot_to_real) # enter real mode
# Restore %es
movl %di, %es
# Restore %ax
movl %si, %ax
int $0x13
setc %bl
data32
call _C_LABEL(real_to_prot) # back to protected mode
movzbl %bl, %eax # return value in %ax
pop %es
popl %edi
popl %esi
popl %ebx
popl %ebp
ret
ENTRY(bioswrite)
movl $1, %eax
ret
/*
#
# biosdinfo(): return a word that represents the
# max number of sectors and heads and drives for this device
#
*/
ENTRY(biosdinfo)
pushl %ebp
movl %esp, %ebp
pushl %ebx
pushl %esi
pushl %edi
movb 8(%ebp), %dl # diskinfo(drive #)
call _C_LABEL(prot_to_real) # enter real mode
movb $0x08, %ah # ask for disk info
int $0x13
jnc ok
/*
* Urk. Call failed. It is not supported for floppies by old BIOS's.
* Guess it's a 15-sector floppy. Initialize all the registers for
* documentation, although we only need head and sector counts.
*/
xorl %bx, %bx # %bh = 0
incw %bx; incw %bx # %bl bits 0-3 = drive type, 2 = 1.2M
movb $79, %ch # max track
movb $15, %cl # max sector
xorl %dx, %dx
incw %dx # floppy drives installed
movb %dl, %dh # max head
# es:di = parameter table
# carry = 0
ok:
data32
call _C_LABEL(real_to_prot) # back to protected mode
xorl %eax, %eax
/* form a longword representing all this gunk */
movb %dh, %ah # max head
andb $0x3f, %cl # mask of cylinder gunk
movb %cl, %al # max sector (and # sectors)
popl %edi
popl %esi
popl %ebx
popl %ebp
ret
|
