1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
|
%{
/* $OpenBSD: scan.l,v 1.4 2003/09/26 19:00:38 deraadt Exp $ */
/*
* Copyright (c) 2003, Otto Moerbeek <otto@drijf.net>
*
* Permission to use, copy, modify, and distribute this software for any
* purpose with or without fee is hereby granted, provided that the above
* copyright notice and this permission notice appear in all copies.
*
* THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES
* WITH REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF
* MERCHANTABILITY AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR
* ANY SPECIAL, DIRECT, INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES
* WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, WHETHER IN AN
* ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTIOUS ACTION, ARISING OUT OF
* OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.
*/
#ifndef lint
static const char rcsid[] = "$OpenBSD: scan.l,v 1.4 2003/09/26 19:00:38 deraadt Exp $";
#endif /* not lint */
#include <err.h>
#include <stdbool.h>
#include <string.h>
#include "extern.h"
#include "y.tab.h"
int lineno;
static char *strbuf = NULL;
static size_t strbuf_sz = 1;
static bool dot_seen;
static void init_strbuf(void);
static void add_str(const char *);
%}
DIGIT [0-9A-F]
%x comment string number
%%
"/*" BEGIN(comment);
<comment>{
"*/" BEGIN(INITIAL);
\n lineno++;
\* ;
[^*\n]+ ;
}
\" BEGIN(string); init_strbuf();
<string>{
[^"\n]+ add_str(yytext);
\n add_str("\n"); lineno++;
\" BEGIN(INITIAL); yylval.str = strbuf; return STRING;
}
{DIGIT}+ {
BEGIN(number);
dot_seen = false;
init_strbuf();
add_str(yytext);
}
\. {
BEGIN(number);
dot_seen = true;
init_strbuf();
add_str(".");
}
<number>{
{DIGIT}+ add_str(yytext);
\. {
if (dot_seen) {
BEGIN(INITIAL);
yylval.str = strbuf;
unput('.');
return NUMBER;
} else {
dot_seen = true;
add_str(".");
}
}
\\\n[ \t]* lineno++;
[^0-9A-F\.] {
if (strcmp(strbuf, ".") == 0) {
warnx("unexpected ascii char 0x%x at line %d",
yytext[0], lineno);
BEGIN(INITIAL);
REJECT;
}
else {
BEGIN(INITIAL);
yylval.str = strbuf;
unput(yytext[0]);
return NUMBER;
}
}
}
"auto" return AUTO;
"break" return BREAK;
"define" return DEFINE;
"ibase" return IBASE;
"if" return IF;
"for" return FOR;
"length" return LENGTH;
"obase" return OBASE;
"quit" return QUIT;
"return" return RETURN;
"scale" return SCALE;
"sqrt" return SQRT;
"while" return WHILE;
"^" return EXPONENT;
"*" return MULTIPLY;
"/" return DIVIDE;
"%" return REMAINDER;
"+" return PLUS;
"-" return MINUS;
"++" return INCR;
"--" return DECR;
"=" yylval.str = ""; return ASSIGN_OP;
"+=" yylval.str = "+"; return ASSIGN_OP;
"-=" yylval.str = "-"; return ASSIGN_OP;
"*=" yylval.str = "*"; return ASSIGN_OP;
"/=" yylval.str = "/"; return ASSIGN_OP;
"%=" yylval.str = "%"; return ASSIGN_OP;
"^=" yylval.str = "^"; return ASSIGN_OP;
"==" return EQUALS;
"<=" return LESS_EQ;
">=" return GREATER_EQ;
"!=" return UNEQUALS;
"<" return LESS;
">" return GREATER;
"," return COMMA;
";" return SEMICOLON;
"(" return LPAR;
")" return RPAR;
"[" return LBRACKET;
"]" return RBRACKET;
"{" return LBRACE;
"}" return RBRACE;
[a-z] yylval.str = yytext; return LETTER;
\\\n lineno++;
\n lineno++; return NEWLINE;
[ \t] ;
. warnx("unexpected character %c at line %d", yytext[0], lineno);
%%
static void
init_strbuf(void)
{
if (strbuf == NULL) {
strbuf = malloc(strbuf_sz);
if (strbuf == NULL)
err(1, "cannot allocate string buffer");
}
strbuf[0] = '\0';
}
static void
add_str(const char *str)
{
size_t arglen;
arglen = strlen(str);
if (strlen(strbuf) + arglen + 1> strbuf_sz) {
size_t newsize;
char *p;
newsize = strbuf_sz + arglen + 1;
p = realloc(strbuf, newsize);
if (p == NULL) {
free(strbuf);
err(1, "cannot realloc string buffer");
}
strbuf_sz = newsize;
strbuf = p;
}
strlcat(strbuf, str, strbuf_sz);
}
void
abort_line(int sig)
{
if (isatty(fileno(yyin))) {
YY_FLUSH_BUFFER;
printf("[\n]P\n");
}
}
|
