blob: 473f531f75019ea6c76d97cbbaef9fa91eb6a50c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
|
package ExtUtils::ParseXS::CountLines;
use strict;
our $VERSION = '3.24';
our $SECTION_END_MARKER;
sub TIEHANDLE {
my ($class, $cfile, $fh) = @_;
$cfile =~ s/\\/\\\\/g;
$cfile =~ s/"/\\"/g;
$SECTION_END_MARKER = qq{#line --- "$cfile"};
return bless {
buffer => '',
fh => $fh,
line_no => 1,
}, $class;
}
sub PRINT {
my $self = shift;
for (@_) {
$self->{buffer} .= $_;
while ($self->{buffer} =~ s/^([^\n]*\n)//) {
my $line = $1;
++$self->{line_no};
$line =~ s|^\#line\s+---(?=\s)|#line $self->{line_no}|;
print {$self->{fh}} $line;
}
}
}
sub PRINTF {
my $self = shift;
my $fmt = shift;
$self->PRINT(sprintf($fmt, @_));
}
sub DESTROY {
# Not necessary if we're careful to end with a "\n"
my $self = shift;
print {$self->{fh}} $self->{buffer};
}
sub UNTIE {
# This sub does nothing, but is necessary for references to be released.
}
sub end_marker {
return $SECTION_END_MARKER;
}
1;
|
