blob: c5613cc31b37480039b6437f30c515a927ff780d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
|
/* $OpenBSD: ld.script,v 1.7 2021/02/11 14:44:13 visa Exp $ */
OUTPUT_FORMAT("elf64-tradbigmips")
OUTPUT_ARCH(mips)
ENTRY(__start)
/*
* When the kernel is built with option NO_RANDOMIZE, PT_OPENBSD_RANDOMIZE
* and :openbsd_randomize are removed by the Makefile.
*/
PHDRS
{
text PT_LOAD;
openbsd_randomize PT_OPENBSD_RANDOMIZE;
}
SECTIONS
{
.text :
{
*(.text .text.* .gnu.linkonce.t.*)
} :text
PROVIDE (etext = .);
.rodata :
{
*(.rodata .rodata.* .gnu.linkonce.r.*)
} :text
. = ALIGN(8);
PROVIDE (__kernel_randomdata = .);
.openbsd.randomdata :
{
__retguard_start = ABSOLUTE(.);
*(.openbsd.randomdata.retguard .openbsd.randomdata.retguard.*)
/* XXX . = ALIGN(0x1000); */
__retguard_end = ABSOLUTE(.);
*(.openbsd.randomdata .openbsd.randomdata.*)
} :text :openbsd_randomize
. = ALIGN(8);
PROVIDE (__kernel_randomdata_end = .);
.data :
{
*(.data .data.* .gnu.linkonce.d.*)
} :text
PROVIDE (edata = .);
.sbss :
{
*(.sbss .sbss.* .gnu.linkonce.sb.* .scommon)
}
.bss :
{
*(.bss .bss.* .gnu.linkonce.b.* COMMON)
}
. = ALIGN(8);
PROVIDE (_end = .);
PROVIDE (end = .);
/DISCARD/ :
{
*(.pdr)
*(.mdebug.abi64)
*(.MIPS.options)
}
}
|
